exemples/fibonacci.jlogo

POUR STATS :t 
	EC PH [Les temps :] :t 
 
	; calcul de la moyenne 
	SOIT "moy 0 
	SOIT "i 1 
	REPETE COMPTE :t [ SOIT "moy SOMME :moy ITEM :i :t SOIT "i SOMME :i 1] 
	SOIT "moy DIV :moy COMPTE :t 
	 
	; calcul de l'ecart type non biais? 
	SOIT "ec 0 
	SOIT "i 1 
	REPETE COMPTE :t [ SOIT "ec SOMME :ec PUISSANCE DIFF ITEM :i :t :moy 2 SOIT "i SOMME :i 1] 
	SOIT "ec PUISSANCE DIV :ec DIFF COMPTE :t 1 0.5 
	 
	; affichage valeurs 
	EC PH [Moyenne :] :moy 
	EC PH [Ecart type :] :ec 
FIN 
 
POUR hEnMs :h 
	SOIT "t PROD 60 ITEM 1 :h 
	SOIT "t PROD 60 SOMME :t ITEM 2 :h 
	SOIT "t PROD 1000 SOMME :t ITEM 3 :h 
	RENDS SOMME :t ITEM 4 :h 
FIN 
 
; ------------------------------------------------------------------------------------------------------------------------ 
 
POUR FIB :N  
	SI PLPE? :N 1 [RENDS :N]  
	RENDS SOMME FIB :N - 2 FIB :N - 1  
FIN  
 
POUR TEST :n 
	EC PH "FIB :n 
	SOIT "debut hEnMs HEURE 
		EC FIB :n 
	SOIT "fin hEnMs HEURE 
	RENDS DIFF :fin :debut "ms 
FIN 
 
POUR TEST2 :n 
	EC PH [Boucle avec somme, ] :n 
 
	SOIT "k 0 
	SOIT "debut hEnMs HEURE 
		REPETE :n [SOIT "k SOMME :k 1] 
	SOIT "fin hEnMs HEURE 
	RENDS DIFF :fin :debut "ms 
FIN 
 
POUR TEST3 :n 
	EC PH [Boucle avec +, ] :n 
	SOIT "k 0 
	SOIT "debut hEnMs HEURE 
		REPETE :n [SOIT "k :k + 1] 
	SOIT "fin hEnMs HEURE 
	RENDS DIFF :fin :debut "ms 
FIN 
 
; ------------------------------------------------------------------------------------------------------------------------ 
 
; boucle somme 
POUR STEST2 :n 
	SOIT "t [] 
	REPETE :n [SOIT "t PH :t TEST2 1000000] 
	STATS :t 
FIN 
 
; boucle avec un plus 
POUR STEST3 :n 
	SOIT "t [] 
	REPETE :n [SOIT "t PH :t TEST3 1000000] 
	STATS :t 
FIN 
 
; fibonacci 
POUR STEST :n 
	SOIT "t [] 
	REPETE :n [SOIT "t PH :t TEST 25] 
	STATS :t 
FIN 
 
; ------------------------------------------------------------------------------------------------------------------------ 
 
TE 
VT 
 
STEST 4 
;STEST2 4 
;STEST3 4 
 
EC "FINI 
 

Retour - Back